MQ7 giao tiếp Nano, Cảm biến khí CO MQ7 + Lcd1602 + Loa + Arduino

MQ7 giao tiếp Nano là dùng Cảm biến khí CO MQ-7 là cảm biến bán dẫn có giá rẻ có khả năng phát hiện khí carbon monoxide có nồng độ từ 10 đến 1000 ppm. Vật liệu tạo ra cảm biến là từ chất SnO2, có độ dẫn điện thấp trong không khí sạch. Cảm biến khí CO MQ7 có độ nhạy cao và thời gian đáp ứng nhanh. Có 2 dạng tín hiệu ngõ ra là analog và digital. Cảm biến có thể hoạt động được ở nhiệt độ từ: -20 độ C đến 50 độ C và tiêu thụ dòng khoảng 150mA tại 5V. Tuổi thọ cao, chi phí thấp.

• Phone : 0967.551.477
• Zalo    : 0967.551.477
• FB      : Huỳnh Nhật Tùng
• Email : dientunhattung@gmail.com
• Địa Chỉ: 106/14 Đường số 51, Phường 14, Gò Vấp, Tp HCM
• Chi tiết: Nhận làm mạch và đồ án Điện tử

1. Linh kiện cần thiết làm mạch đọc cảm biến khí CO MQ7 giao tiếp Nano

1.1 Vi điều khiển Arduino trong mạch đọc cảm biến khí CO MQ7 giao tiếp Nano

a. Giới thiệu

Arduino Nano có chức năng tương tự như Arduino Duemilanove nhưng khác nhau về dạng mạch. Nano được tích hợp vi điều khiển ATmega328P, giống như Arduino UNO. Sự khác biệt chính giữa chúng là bảng UNO có dạng PDIP (Plastic Dual-In-line Package) với 30 chân còn Nano có sẵn trong TQFP (plastic quad flat pack) với 32 chân. Trong khi UNO có 6 cổng ADC thì Nano có 8 cổng ADC. Bảng Nano không có giắc nguồn DC như các bo mạch Arduino khác, mà thay vào đó có cổng mini-USB. 

Cổng này được sử dụng cho cả việc lập trình và bộ giám sát nối tiếp. Tính năng hấp dẫn của arduino Nano là nó sẽ chọn công xuất lớn nhất với hiệu điện thế của nó. Arduino Nano là phiên bản nhỏ gọn của Arduino Uno R3 sử dụng MCU ATmega328P-AU dán, vì cùng MCU nên mọi tính năng hay chương trình chạy trên Arduino Uno đều có thể sử dụng trên Arduino Nano, một ưu điểm của Arduino Nano là vì sử dụng phiên bản IC dán nên sẽ có thêm 2 chân Analog A6, A7 so với Arduino Uno.

Chức năng khác

Vi xử lý có rất nhiều loại bắt đầu từ 4 bit cho đến 32 bit, vi xử lý 4 bit hiện nay không còn nhưng vi xử lý 8 bit vẫn còn mặc dù đã có vi xử lý 64 bit. Lý do sự tồn tại của vi xử lý 8 bit là phù hợp với một số yêu cầu điều khiển trong công nghiệp. Các vi xử lý 32 bit, 64 bit thường sử dụng cho các máy tính vì khối lượng dữ liệu của máy tính rất lớn nên cần các vi xử lý càng mạnh càng tốt. Các hệ thống điều khiển trong công nghiệp sử dụng các vi xử lý 8 bit hay 16 bit như hệ thống điện của xe hơi, hệ thống điều hòa, hệ thống điều khiển các dây chuyền sản xuất, …

b. Chức năng của Arduino Nano:

Chân ICSP

• Các chân: 1, 2, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15 và 16 Như đã đề cập trước đó, Arduino Nano có 14 ngõ vào/ra digital. Các chân làm việc với điện áp tối đa là 5V. Mỗi chân có thể cung cấp hoặc nhận dòng điện 40mA và có điện trở kéo lên khoảng 20-50kΩ. Các chân có thể được sử dụng làm đầu vào hoặc đầu ra, sử dụng các hàm pinMode (), digitalWrite () và digitalRead ().

Các chức năng khác

• Ngoài các chức năng đầu vào và đầu ra số, các chân này cũng có một số chức năng bổ sung.
• Chân 1, 2: Chân nối tiếp Hai chân nhận RX và truyền TX này được sử dụng để truyền dữ liệu nối tiếp TTL. Các chân RX và TX được kết nối với các chân tương ứng của chip nối tiếp USB tới TTL.
• Chân 6, 8, 9, 12, 13 và 14: Chân PWM Mỗi chân số này cung cấp tín hiệu điều chế độ rộng xung 8 bit. Tín hiệu PWM có thể được tạo ra bằng cách sử dụng hàm analogWrite ().
• Chân 5, 6: Ngắt Khi chúng ta cần cung cấp một ngắt ngoài cho bộ xử lý hoặc bộ điều khiển khác, chúng ta có thể sử dụng các chân này. Các chân này có thể được sử dụng để cho phép ngắt INT0 và INT1 tương ứng bằng cách sử dụng hàm attachInterrupt (). Các chân có thể được sử dụng để kích hoạt ba loại ngắt như ngắt trên giá trị thấp, tăng hoặc giảm mức ngắt và thay đổi giá trị ngắt.

Chức năng khác

• Khi bạn không muốn dữ liệu được truyền đi không đồng bộ, bạn có thể sử dụng các chân ngoại vi nối tiếp này. Các chân này hỗ trợ giao tiếp đồng bộ với SCK. Mặc dù phần cứng có tính năng này nhưng phần mềm Arduino lại không có. Vì vậy, bạn phải sử dụng thư viện SPI để sử dụng tính năng này.
• Chân 16: Led Khi bạn sử dụng chân 16, đèn led trên bo mạch sẽ sáng.
• Chân 18, 19, 20, 21, 22, 23, 24, 25 và 26 : Ngõ vào/ra tương tự Như đã đề cập trước đó UNO có 6 chân đầu vào tương tự nhưng Arduino Nano có 8 đầu vào tương tự (19 đến 26), được đánh dấu A0 đến A7. Điều này có nghĩa là bạn có thể kết nối 8 kênh đầu vào tương tự để xử lý. Mỗi chân tương tự này có một ADC có độ phân giải 1024 bit (do đó nó sẽ cho giá trị 1024). Theo mặc định, các chân được đo từ mặt đất đến 5V. Nếu bạn muốn điện áp tham chiếu là 0V đến 3.3V, có thể nối với nguồn 3.3V cho chân AREF (pin thứ 18) bằng cách sử dụng chức năng analogReference (). Tương tự như các chân digital trong Nano, các chân analog cũng có một số chức năng khác.
• Chân 23, 24 như A4 và A5: chuẩn giao tiếp I2C

Chức năng khác

• Khi giao tiếp SPI cũng có những nhược điểm của nó như cần 4 chân và giới hạn trong một thiết bị. Đối với truyền thông đường dài, cần sử dụng giao thức I2C. I2C hỗ trợ chỉ với hai dây. Một cho xung (SCL) và một cho dữ liệu (SDA). Để sử dụng tính năng I2C này, chúng ta cần phải nhập một thư viện có tên là Thư viện Wire.
• Chân 18: AREF : Điện áp tham chiếu cho đầu vào dùng cho việc chuyển đổi ADC.
• Chân 28 : RESET: Đây là chân reset mạch khi chúng ta nhấn nút rên bo. Thường được sử dụng để được kết nối với thiết bị chuyển mạch để sử dụng làm nút reset.
• Chân 13, 14, 15 và 16: Giao tiếp SPI

1.2 Cảm biến khí CO MQ7 giao tiếp Nano

a. Giới thiệu khí CO MQ7 giao tiếp Nano

Cảm biến khí CO MQ-7 là cảm biến bán dẫn có giá rẻ có khả năng phát hiện khí carbon monoxide có nồng độ từ 10 đến 1000 ppm. Vật liệu tạo ra cảm biến là từ chất SnO2, có độ dẫn điện thấp trong không khí sạch. Cảm biến khí CO MQ7 có độ nhạy cao và thời gian đáp ứng nhanh. Có 2 dạng tín hiệu ngõ ra là analog và digital. Cảm biến có thể hoạt động được ở nhiệt độ từ: -20 độ C đến 50 độ C và tiêu thụ dòng khoảng 150mA tại 5V. Tuổi thọ cao, chi phí thấp.

b. Thông số kỹ thuật cảm biến khí CO MQ7

• Điện áp cung cấp: 3 ~ 5V DC.
• Sử dụng chip so sánh LM393 và MQ-7.
• Hai dạng tín hiệu đầu ra (digital và analog).
• Tín hiệu analog từ 0~5V.
• Dải phát hiện từ 10 đến 1000ppm.
• Công suất tiêu thụ: khoảng 350mW.
• Nhiệt độ hoạt động: -10C đến 50C.
• Kích thước: 33 x 20 x 16mm.

c. Các loại khí phát hiện của cảm biến khí khí CO MQ7

• LPG ( Khí hóa lỏng)
•  Khí CO
•  Methane
•  Alcohol
•  Khí gas
•  Khói.
• iso-butan
• propan

d. Nguyên lý hoạt động cảm biến khí CO MQ7 giao tiếp Nano

Cảm biến MQ-7 (Gas sensor) đo khí CO chuyển thành điện áp đưa ra chân AOUT. Biến trở trên Module có chức năng điều chỉnh điện áp tham chiếu (ngưỡng), khi cảm biến MQ-6 phát hiện khí CO đến ngưỡng thì chân DOUT sẽ đảo trạng thái.

e. Sơ đồ chân cảm biến khí CO MQ7

• VCC ↔ 2.5V ~ 5.0V
• GND ↔ GND
• AOUT ↔ MCU.IO (dùng tín hiệu analog)
• DOUT ↔ MCU.IO (dùng tín hiệu số)

f. Định nghĩa khí CO MQ7

CO (hay còn gọi Cacbon mônôxít) : Khí không màu, không mùi, không vị, nặng hơn không khí, nên hay lắng đọng dưới mặt đất hay các hố sâu. Là sản phẩm trong sự cháy không hoàn toàn của các bon và các hợp chất chứa các bon như xăng, dầu, gỗ… Cacbon mônôxít có độc tính cao, cực kỳ nguy hiểm với sức khỏe con người. nếu bị hít một lượng lớn sẽ gây thương tổn cho cơ thể. Chính vì thế việc giám sát khí CO rất quan trọng để bảo vệ sưc khỏe người lao động, đặc biệt những nơi làm việc kín như hầm lò, nhà máy ..

g. Tính năng cảm biến khí CO MQ7

• Cảm biến MQ-7 có thể phát hiện khí CO tập trung những nơi khác nhau từ 10 đến 1000ppm
• Cảm biến này với độ nhạy cao và thời gian đáp ứng nhanh. Tín hiệu ngõ ra dạng analog và digital. Cảm biến có thể hoạt động được ở nhiệt độ từ khoảng: -10C đến 50C và tiêu thụ dòng khoảng 150mA tại 5V.
• Tuỳ thuộc vào nhu cầu sử dụng nên chúng ta sẽ lựa chọn cho mình một bộ sản phẩm sao cho phù hợp

1.3 Còi Buzzer 5V cảm biến khí CO MQ7 giao tiếp Nano

a. Giới thiệu

Còi Buzzer 5VDC có tuổi thọ cao, hiệu suất ổn định, chất lượng tốt, được sản xuất nhỏ gọn phù hợp thiết kế với các mạch còi buzzer nhỏ gọn, mạch báo động.

b. Thông số kỹ thuật

• Nguồn : 3.5V – 5.5V
• Dòng điện tiêu thụ: <25mA
• Tần số cộng hưởng: 2300Hz ± 500Hz
• Biên độ âm thanh: >80 dB
• Nhiệt độ hoạt động:-20 °C đến +70 °C
• Kích thước : Đường kính 12mm, cao 9,7mm

2. Hướng dẫn đồ án cảm biến khí CO MQ7 giao tiếp Nano hiển thị LCD1602

Phần này chưa được chia sẻ.

LIÊN HỆ thông tin ở TẠI ĐÂY để được hổ trợ tốt hơn.

Phần cứng

Phần mềm

int time_scale = 8; //time scale: we altered main system timer, so now all functions like millis(), delay() etc 

void setTimer0PWM(byte chA, byte chB) //pins D5 and D6
{
  TCCR0A = 0b10110011; //OCA normal,OCB inverted, fast pwm
  TCCR0B = 0b010; //8 prescaler - instead of system's default 64 prescaler - thus time moves 8 times faster
  OCR0A = chA; //0..255
  OCR0B = chB;
}

void setTimer2PWM(byte chA, byte chB) //pins D11 and D3
{
  TCCR2A = 0b10100011; //OCA,OCB, fast pwm
  TCCR2B = 0b001; //no prescaler
  OCR2A = chA; //0..255
  OCR2B = chB;
}

void setTimer1PWM(int chA, int chB) //pins D9 and D10
{
  TCCR1A = 0b10100011; //OCA,OCB, fast pwm
  TCCR1B = 0b1001; //no prescaler
  OCR1A = chA; //0..1023
  OCR1B = chB;
}

float opt_voltage = 0;
byte opt_width = 240; //default reasonable value

void pwm_adjust()
{
  float previous_v = 5.0; //voltage at previous attempt
  float raw2v = 5.0 / 1024.0;//coefficient to convert Arduino's 
  for(int w = 0; w < 250; w++)
  {
    setTimer2PWM(0, w);
    float avg_v = 0;
    for(int x = 0; x < 100; x ++) //measure over about 100ms to ensure stable result
    {
      avg_v += analogRead(A1);
      delay(time_scale);
    }
    avg_v *= 0.01;
    avg_v *= raw2v;
    Serial.print("adjusting PWM w=");
    Serial.print(w);
    Serial.print(", V=");
    Serial.println(avg_v);
    if(avg_v < 3.6 && previous_v > 3.6) //we found optimal width
    {
      float dnew = 3.6 - avg_v; //now we need to find if current one
      float dprev = previous_v - 3.6;//or previous one is better
      if(dnew < dprev) //if new one is closer to 1.4 then return it
      {
        opt_voltage = avg_v;
        opt_width = w;
        return;
      }
      else //else return previous one
      {
        opt_voltage = previous_v;
        opt_width = w-1;
        return;
      }
    }
    previous_v = avg_v;
  }
}

float alarm_ppm_threshold = 100; //threshold CO concentration for buzzer alarm to be turned on,
float red_threshold = 40; //threshold when green LED is turned on red turns on
float reference_resistor_kOhm = 10.0; //fill correct resisor value if you are using not 10k reference

float sensor_reading_clean_air = 620; //fill raw sensor value at the end of measurement phase (before heating starts) in clean air here! That is critical for proper calculation
float sensor_reading_100_ppm_CO = -1; //if you can measure it 

float sensor_100ppm_CO_resistance_kOhm; //calculated from sensor_reading_100_ppm_CO variable
float sensor_base_resistance_kOhm; //calculated from sensor_reading_clean_air variable

byte phase = 0; //1 - high voltage, 0 - low voltage, we start from measuring
unsigned long prev_ms = 0; //milliseconds in previous cycle
unsigned long sec10 = 0; //this timer is updated 10 times per second,

unsigned long high_on = 0; //time when we started high temperature cycle
unsigned long low_on = 0; //time when we started low temperature cycle
unsigned long last_print = 0; //time when we last printed message in serial

float sens_val = 0; //current smoothed sensor value
float last_CO_ppm_measurement = 0; //CO concentration at the end of previous measurement cycle

float raw_value_to_CO_ppm(float value)
{
  if(value < 1) return -1; //wrong input value
  sensor_base_resistance_kOhm = reference_resistor_kOhm * 1023 / sensor_reading_clean_air - reference_resistor_kOhm;
  if(sensor_reading_100_ppm_CO > 0)
  {
    sensor_100ppm_CO_resistance_kOhm = reference_resistor_kOhm * 1023 / sensor_reading_100_ppm_CO - reference_resistor_kOhm;
  }
  else
  {
    sensor_100ppm_CO_resistance_kOhm = sensor_base_resistance_kOhm * 0.25;
  }
  float sensor_R_kOhm = reference_resistor_kOhm * 1023 / value - reference_resistor_kOhm;
  float R_relation = sensor_100ppm_CO_resistance_kOhm / sensor_R_kOhm;
  float CO_ppm = 134 * R_relation - 35;
  if(CO_ppm < 0) CO_ppm = 0;
  return CO_ppm;
}

void startMeasurementPhase()
{
  phase = 0;
  low_on = sec10;
  setTimer2PWM(0, opt_width);
}

void startHeatingPhase()
{
  phase = 1;
  high_on = sec10;
  setTimer2PWM(0, 255);
}
void setLEDs(int br_green, int br_red)
{
  if(br_red < 0) br_red = 0;
  if(br_red > 100) br_red = 100;
  if(br_green < 0) br_green = 0;
  if(br_green > 100) br_green = 100;

  float br = br_red;
  br *= 0.01;
  br = (exp(br)-1) / 1.7183 * 1023.0;
  float bg = br_green;
  bg *= 0.01;
  bg = (exp(bg)-1) / 1.7183 * 1023.0;
  if(br < 0) br = 0;
  if(br > 1023) br = 1023;
  if(bg < 0) bg = 0;
  if(bg > 1023) bg = 1023;

  setTimer1PWM(1023-br, 1023-bg);
}
void buzz_on()
{
  setTimer0PWM(128, 128);
}
void buzz_off()
{
  setTimer0PWM(255, 255);
}
void buzz_beep()
{
  byte sp = sec10%15;
  if(sp == 0)
    buzz_on();
  if(sp == 1)
    buzz_off();
  if(sp == 2)
    buzz_on();
  if(sp == 3)
    buzz_off();
  if(sp == 4)
    buzz_on();
  if(sp == 5)
    buzz_off();
}

void setup() {

  pinMode(5, OUTPUT);
  pinMode(6, OUTPUT);
  pinMode(3, OUTPUT);
  pinMode(9, OUTPUT);
  pinMode(10, OUTPUT);
  pinMode(A0, INPUT);
  pinMode(A1, INPUT);
  setTimer1PWM(1023, 0);
  analogReference(DEFAULT);
  Serial.begin(9600);

  pwm_adjust();

  Serial.print("PWM result: width ");
  Serial.print(opt_width);
  Serial.print(", voltage ");
  Serial.println(opt_voltage);
  Serial.println("Data output: raw A0 value, heating on/off (0.1 off 1000.1 on), CO ppm from last measurement cycle");
  //beep buzzer in the beginning to indicate that it works
  buzz_on();
  delay(100*time_scale);
  buzz_off();
  delay(100*time_scale);
  buzz_on();
  delay(100*time_scale);
  buzz_off();
  delay(100*time_scale);
  buzz_on();
  delay(100*time_scale);
  buzz_off();
  delay(100*time_scale);

  startMeasurementPhase(); //start from measurement
}

void loop() 
{
  unsigned long ms = millis();
  int dt = ms - prev_ms;
  if(dt > 100*time_scale || dt < 0) 
  {
    prev_ms = ms; //store previous cycle time
    sec10++; //increase 0.1s counter
    if(sec10%10 == 1) //we want LEDs to blink periodically
    {
      setTimer1PWM(1023, 1023); //blink LEDs once per second
      //use %100 to blink once per 10 seconds, %2 to blink 5 times per second
    }
    else //all other time we calculate LEDs and buzzer state
    {
      int br_red = 0, br_green = 0; //brightness from 1 to 100, setLEDs function handles converting it into timer settings
      if(last_CO_ppm_measurement <= red_threshold) //turn green LED if we are below 30 PPM
      {//the brighter it is, the lower concentration is
        br_red = 0; //turn off red
        br_green = (red_threshold - last_CO_ppm_measurement)*100.0/red_threshold; //the more negative is concentration, the higher is value
        if(br_green < 1) br_green = 1; //don't turn off completely
      }
      else //if we are above threshold, turn on red one
      {
        br_green = 0; //keep green off
        br_red = (last_CO_ppm_measurement-red_threshold)*100.0/red_threshold; //the higher is concentration, the higher is this value
        if(br_red < 1) br_red = 1; //don't turn off completely
      }

      if(last_CO_ppm_measurement > alarm_ppm_threshold) //if at 50 seconds of measurement cycle we are above threshold 
        buzz_beep();
      else
        buzz_off();

      setLEDs(br_green, br_red); //set LEDs brightness
    }
  }
  if(phase == 1 && sec10 - high_on > 600) //60 seconds of heating ended?
    startMeasurementPhase();
  if(phase == 0 && sec10 - low_on > 900) //90 seconds of measurement ended?
  {
    last_CO_ppm_measurement = raw_value_to_CO_ppm(sens_val);
    startHeatingPhase();
  }

  float v = analogRead(A0); //reading value
  sens_val *= 0.999; //applying exponential averaging using formula
  sens_val += 0.001*v; // average = old_average*a + (1-a)*new_reading
  if(sec10 - last_print > 9) //print measurement result into serial 2 times per second
  {
    last_print = sec10;
    Serial.print(sens_val);
    Serial.print(" ");
    Serial.print(0.1 + phase*1000);
    Serial.print(" ");
    Serial.println(last_CO_ppm_measurement);
  }
}

3. Hoạt động của mạch đọc cảm biến khí CO MQ7

Khi cấp điện hệ thống hoạt động, vi điều khiển đưa tín hiệu ban đầu cho lcd1602 hiển thị thông tin người dùng, lúc này vi điều khiển chờ tín hiệu được gửi vào từ cảm biến khí ga MQ7 về giá trị Analog và Digital. Khi nhận được tín hiệu vi điều khiển xử lý và gửi giá trị nồng độ đọc được từ khí ga ra ngoài màn hình để hiển thị giá trị, và hiển thị chỉ số cảnh báo khi quá ngưỡng.

4. Cụ thể hoạt động của mạch đọc cảm biến khí CO MQ7 giao tiếp Nano

Chúc các bạn thành công…!!!